Выполняет родительский метод класса из метода подкласса.

CИмяКласса::CМетод

Комментарии

Оператор :: используется для выполнения метода родительского класса из метода подкласса. Когда Вы создаете подкласс, методы подкласса автоматически унаследованы из родительского класса .. Оператор :: дает возможность выполнять методы родительского класса непосредственно в методе подкласса. Определение подкласса в примере демонстрирует как используется оператор ::  для выполнения родительского метода в пределах метода подкласса.

Для дополнительной информации см. также Объектно-ориентированное программирование.

Пример

Представленный пример создает форму и добавляет две командные кнопки. По нажатию на первую кнопку Вы можете выйти из формы, при нажатии на вторую кнопку, cmdAnotherButton, вызывается событие Click родительской кнопки cmdQuit. Это возможно благодаря Субклассированию. Оператор Области действия :: вызывает код родительского класса из кода субклассированного объекта.

  Копировать Код
frmMyForm = CREATEOBJECT("Form")
frmMyForm.Width  = 450
frmMyForm.Height   = 100
frmMyForm.Caption  = "Scope Resolution Example"
frmMyForm.AutoCenter =.T.
frmMyForm.AddObject("cmdQuit","cmdQuitButton")
frmMyForm.AddObject("cmdAnother","cmdAnotherButton")
frmMyForm.SHOW       && Display the form
READ EVENTS        && Start event processing

Представленный пример определяет две командные кнопки. Первая кнопка используется для субклассирования второй командной кнопки. Субклассирование позволяет наследовать , например, свойства FontBold и ForeColor, определенные для cmdQuit, которые явно не указываются для кнопки  cmdAnotherButton. Мы определяем кнопку cmdAnotherButton как подкласс от родителя cmdQuitButton. В результате, эта кнопка приобретет все атрибуты определенные выше для cmdQuitButton

  Копировать Код
DEFINE CLASS cmdQuitButton AS CommandButton 
  Caption  = "\<Quit"   && надпись командной кнопки
  Left   = 175    && левая сторона кнопки
  Top    = 60     && верхняя сторона кнопки
  Height   = 25     && высота кнопки
  Visible  = .T.    && активация кнопки на форме
  FontItalic = .T.    && включить опцию текста Italic
  ForeColor  = RGB(0,0,255) && изменить цвет символов

  PROCEDURE Click
  WAIT WINDOW "Executing the CLICK procedure for cmdQuit." TIMEOUT 1
  CLEAR EVENTS     && остановить контроль событий
ENDDEFINE
DEFINE CLASS cmdAnotherButton AS cmdQuitButton

  Caption = "Click to quit"
  Left  = 175
  Top   = 30
  Height  = 25
   
  PROCEDURE Click
  WAIT WINDOW "Click event for button: cmdAnotherButton" TIMEOUT 1
  cmdQuitButton::Click
ENDDEFINE

См. также