Возвращает имя файла, из которого был создан "linked" OLE объект. В design time, указывает имя связанного файла. Только для чтения как в design, так и в run time для существующего объекта, но может быть установлен для объекта при его создании.

Object.DocumentFile[ = cFileName]

Expand imageВозвращаемое значение

cFileName

Имя файла, с которым связан объект. Имя включает полный путь к файлу.

Expand imageПримечания

Применяется к: OLE Bound Control | OLE Container Control

DocumentFile содержит пустую строку для внедренных "embedded" (not linked) объектов.

Вы устанавливаете свойство DocumentFile связанного (linked) OLE объекта, используя диалоговый блок Insert Object, когда вы изначально добавляете OLE контейнер в форму. Вы, кроме того, можете установить это свойство, когда создаете OLE объект, используя команду APPEND GENERAL или когда определяете объект в коде, как часть описания класса.

Перед определением содержимого OLE объекта с помощью свойства DocumentFile, укажите Automation server приложения путем установки свойства объекта OLEClass.

Expand imageПример

Приведенный ниже пример добавляет в форму управляющий элемент OLE Container и использует свойства DocumentFile и OleClass для указания таблицы Microsoft Excel в качестве файла редактирования и Microsoft Excel в качестве Automation server.

Свойство DocumentFile указывает рабочий лист с именем Book1.xls в каталоге EXCEL на диске C. Этот пример не будет работать должным образом, если файл и каталог, указанные в свойстве DocumentFile не существуют; поэтому необходимо подредактировать свойство DocumentFile для указания существующих каталога и файла.

Для активизации редактирования рабочего листа используется метод DoVerb.
  CopyCode imageСкопировать код 
frmMyForm = CREATEOBJECT('form')  && Создается форма
frmMyForm.Closable = .F.  && Disable the Control menu box

frmMyForm.AddObject('cmdCommand1','cmdMyCmdBtn')  && Добавляется командная кнопка
frmMyForm.AddObject("oleObject","oleExcelObject")  && Добавляется OLE object

frmMyForm.cmdCommand1.Visible=.T.  && отображается командная кнопка "Quit"

frmMyForm.oleObject.Visible=.T.  && Отображается OLE control
frmMyForm.oleObject.Height = 50  && задается высота OLE control

frmMyForm.Show  && отображается форма

frmMyForm.oleObject.DoVerb(-1)  && -1 для редактирования

READ EVENTS  && Начинается обработка событий

DEFINE CLASS oleExcelObject as OLEControl
   OleClass ="Excel.Sheet"  && Имя сервера
   DocumentFile = "C:\EXCEL\BOOK1.XLS"  && Этот файл должен существовать
ENDDEFINE

DEFINE CLASS cmdMyCmdBtn AS CommandButton  && Создается командная кнопкв
   Caption = '\<Quit'  && Определяется заголовок командной кнопки
   Cancel = .T.  && Командная кнопка устанавливется,
                 && кнопка прерывания по умолчанию (Default Cancel) (Esc)
   Left = 125  && Определяется колонка размещения командной кнопки
   Top = 210  && Определяется строка размещения командной кнопки
   Height = 25  && Определяется высота командной кнопки

   PROCEDURE Click
      CLEAR EVENTS  && Прекращение обработки событий, закрытие формы
ENDDEFINE

Expand image Смотрите также