Направляет вывод от \ | \\ и команды слияния текста TEXT ... ENDTEXT к отрытому на нижнем уровне файлу. 

_TEXT = nFileHandle

Параметры

nFileHandle

Определяет числовое значение, которое определяет отрытый на нижнем уровне файл, в который направлен вывод.

Замечания

\ | \\ и TEXT ... ENDTEXT облегчают объединение текста из содержания таблиц, переменных памяти, и результатов функций и выражений. Вывод, сгенерированный командами этого текстового слияния может быть направлен на экран или в окно или в отрытый на нижнем уровне файл. системная переменная памяти _TEXT позволяет вывод прямого текстового слияния этими командами в отрытый на нижнем уровне файл.

Чтобы посылать вывод через \ и \\ и команду слияния текста TEXT ... ENDTEXT к отрытому на нижнем уровне файлу, включите предложение TO FileName в SET TEXTMERGE. Дескриптор файла FileName сохраняется в _TEXT. Если дескриптор файла другого отрытого на нижнем уровне файла, был предварительно сохранен в _TEXT, то первый отрытый на нижнем уровне файл закрывается.

FCREATE( ) создает и открывает на нижнем уровне файлы, а FOPEN( ) открывает только существующие файлы. Эти функции возвращают положительный дескриптор файла, если файл успешно создан или открыт. Сохранение этого дескриптора файла в _TEXT направляет любой последующий вывод от \, \\ и команды слияния текста TEXT ... ENDTEXT в файл. Используйте STORE или =, чтобы сохранить дескриптор файла в _TEXT. Вы должны отрыть на нижнем уровне файл с привилегиями записи для того, чтобы получить вывод от команд текстового слияния.

Вы можете закрыть отрытые на нижнем уровне файлы FCLOSE( ) или CLOSE ALL. Вы можете также использовать SET TEXTMERGE TO без имени файла, чтобы закрыть отрытый на нижнем уровне файл, дескриптор которого сохранен в _TEXT.

Значение по умолчанию для _TEXT - -1. Если Вы направляете вывод текстового слияния в файл, дескриптор файла которого сохранен в _TEXT, Вы можете отменить вывод в этот файл, не закрывая его, но присваивая -1 переменной _TEXT. Присваивая различные дескрипторы файлов и -1 переменной _TEXT, Вы можете организовать вывод текстового слияния, чередуя разные файлы.

Пример

Следующая программа демонстрирует как направить вывод текстового слияния, чтобы чередовать файлы:

Скопировать код 
SET TALK OFF
SET TEXTMERGE ON NOSHOW      && Enable text merge, no output to screen
SET TEXTMERGE DELIMITERS TO   && Default text merge delimiters <<,>>
SET TEXTMERGE TO date.txt   && Create and send output to date.txt
STORE _TEXT TO gcDateHandle   && Save date.txt's file handle
STORE -1 TO _TEXT         && Output off to date.txt; keep it open
SET TEXTMERGE TO time.txt   && Create and send output to time.txt
STORE _TEXT TO gcTimeHandle   && Save time.txt's file handle
*** Send the following text to time.txt ***
\The time is:
STORE gcDateHandle TO _TEXT    && Now direct output to date.txt
*** Send the following text to date.txt ***
\Today's date is:
STORE gcTimeHandle TO _TEXT   && Now direct output to time.txt
*** Output the time on the same line ***
\\ <<TIME( )>>
STORE gcDateHandle TO _TEXT   && Now direct output to date.txt
*** Output the date on the same line ***
\\ <<DATE( )>>
CLOSE ALL  && Close all files
TYPE date.txt  && See what's in this file...
WAIT WINDOW  && Pause
TYPE time.txt  && ...and what's in this file
ERASE date.txt
ERASE time.txt

См. Также