Определяет направление наклона управляющего элемента Line или сглаженных углов (кривые Безье) для полигональной линии, нарисованной с помощью Line. Редактируемое, как design, так и в run time.

Line.LineSlant [= cSlant]

Expand imageВозвращаемое значение

cSlant

Определяет направление наклона управляющего элемента Line или сглаженные углы для полигональных линий, нарисованных с помощью Line.

В приведенной ниже таблице перечислены значения для cSlant.

cSlant Описание

\

Наклон линии идет в направлении от левого верхнего угла в правому нижнему. (По умолчанию)

/

Наклон линии идет в направлении от левого нижнего угла в правому верхнему.

S или s

Линия прорисовывается как кривая Безье (Bezier curve), когда для свойства PolyPoints указан действительный массив координат. Для удаления этого значения присвойте свойству LineSlant значение "\" или "/".

ЗамечаниеЗамечание

Массив свойство PolyPoints должен определять суммарно (3n + 1) координат, где n представляет номер кривых, которые вы желаете отобразить, как кривые Безье. Если PolyPoints не содержит координат, которые образуют действительный полигон, а для свойства LineSlant указана установка "S" или "s", то линии не будут прорисованы.

Для получения более подробной информации, смотрите Свойство PolyPoints.

Expand imageПримечания

Применяется к управляющему элементу: Line

Expand imageПример

Приведенный ниже пример создает форму с управляющим элементом Line и тремя командными кнопками, которые демонстрируют три значения для свойства LineSlant.

  CopyCode imageСкопировать код
Public oForm
oForm = Createobject('Form')
With oForm
   .AddObject('linSample','Line')
   .AddObject('cmdSlantUp','cmdSlantUp')
   .AddObject('cmdSlantDown','cmdSlantDown')
   .AddObject('cmdBezier','cmdBezier')

   .linSample.Top = 10
   .linSample.Left = 25
   .linSample.Width = 300
   .linSample.Height = 200

   .SetAll('Visible', .T.)

* Создается массив точек, который определяет кривую.
   Dimension aBezierPoints[4,2]
      aBezierPoints[1,1]= 0
      aBezierPoints[1,2]= 0
      aBezierPoints[2,1]= 100
      aBezierPoints[2,2]= 25
      aBezierPoints[3,1]= 0
      aBezierPoints[3,2]= 75
      aBezierPoints[4,1]= 100
      aBezierPoints[4,2]= 100
Endwith

oForm.Show(1)

* Определяется командная кнопка, которая изменит направление наклона линии.
Define Class cmdSlantUp As CommandButton
   Caption = 'Slant \<Up (/)'
   Left = 25
   Top = 220
   Height = 25

   Procedure Click
      Thisform.linSample.Polypoints = ""
      Thisform.linSample.LineSlant = '/'  && Slant up
   Endproc
Enddefine

*  Определяется командная кнопка, которая изменит направление наклона линии.
Define Class cmdSlantDown As CommandButton
   Caption = 'Slant \<Down (\)'
   Left = 125
   Top = 220
   Height = 25

   Procedure Click
      Thisform.linSample.Polypoints = ""
      Thisform.linSample.LineSlant = '\'  && Slant down
   Endproc
Enddefine

*  Определяется командная кнопка, которая превратит линию в кривую Безье.
Define Class cmdBezier As CommandButton
   Caption = 'Be\<zier Curve (S) '
   Left = 225
   Top = 220
   Height = 25

   Procedure Click
      Thisform.linSample.Polypoints = "aBezierPoints" && Определяет точки кривой.
      Thisform.linSample.LineSlant = 'S' && Определяет, что линия будет отображена как кривая.
      Thisform.linSample.Visible = .T.
      Thisform.Visible = .T.
   Endproc
Enddefine

Expand imageСмотрите также