Добавляет файл в проект.

Object.Add(cFileName)

Параметры

cFileName

Определяет имя файла, для добавления в проект. Если файл, который вы определяете, не существует генерируется сообщение об ошибке. Если открыто окно Project Manager, то оно обновляется после добавления файла.

Expand imageВозвращаемое значение

Объект

Expand imageПримечание

Применимо к: Files Collection

Метод Add - метод для коллекции файлов. Когда файл добавлен к проекту методом Add, для файла создается объект File, и объект File добавляется в колекцию Files.

Ссылка на объект для добавляемого файла возвращается если файл успешно добавлен в проект. Значение null возвращается, если файл не может быть добавлен в проект.

Событие QueryAddFile происходит непосредственно перед тем, как файл добавлен в проект. Если задан NODEFAULT в событии QueryAddFile, файл не добавляется в проект.

Включите NODEFAULT в событие QueryAddFile для предотваращения добавления файла в проект.

Expand imageПример

Следующий пример программно создает проект и затем строит выполнимое (EXE) из проекта. Используется метод Add для добавления програмного кода в проект.
  CopyCode imageCopy Code
SET SAFETY OFF
LOCAL lcCode
TEXT TO lcCode NOSHOW
CLEAR
PUBLIC loForm

SET TALK OFF
SET DELETED ON
SET EXCLUSIVE OFF
SET CENTURY ON

ON SHUTDOWN clear events
loForm = CREATEOBJECT('Test1')
loForm.Show(0)
READ EVENTS
ON SHUTDOWN
RETURN

DEFINE CLASS Test1 as Form
 Top = 0
 Left = 0
 Width = 240
 Height = 150
 Caption = 'Add Method sample'
 ShowWindow = 2

 ADD OBJECT cmdClose as CommandButton WITH ;
  Caption = '\<Close', ;
  Top = 80, ;
  Left = 80, ;
  Height = 24, ;
  Width = 80

 ADD OBJECT lblTitle as Label WITH ;
  Top = 30, ;
  Left = 40, ;
  Height = 34, ;
  Width = 160, ;
  Caption = 'This sample was made programmatically.';
  WordWrap = .t.

 PROCEDURE Init
  SET TALK off
  ThisForm.AutoCenter = .t.
 ENDPROC
 PROCEDURE Unload
  CLEAR EVENTS
 ENDPROC
 PROCEDURE cmdClose.Click
  ThisForm.Release()
 ENDPROC
ENDDEFINE
ENDTEXT

STRTOFILE(lcCode, 'addsample.prg')
CREATE PROJECT 'AddSample' NOSHOW NOWAIT SAVE
LOCAL loPJX
loPJX = _VFP.ActiveProject
WITH loPJX
 .Files.Add('addsample.prg')
 .SetMain('addsample.prg')
 .Build('addsample.exe',3,.t.,.t.,.f.)
 .Close()
ENDWITH
RUN /n addsample.exe

Expand imageСмотрите также