Создает единственную командную кнопку.

CommandButton

Expand imageЗамечания

Командная кнопка типично используется, чтобы запустить событие, которое выполняет действие, такое как закрытия формы, перемещение на другую запись,печать отчета, и т. д. Используйте элемент управления CommandGroup для создания набора командных кнопок, которыми вы можете манипулировать индивидуально или групой.

Используйте свойство Caption, чтобы определить текст, который появляется на командной кнопке. Используйте свойство Picture , чтобы определить картинку для командной кнопки.

Вы можете выбрать командную кнопку кликая по ней, и если свойство Default установлено в "истина" (.T.), нажимая клавишу ENTER когда командная кнопка выбрана. Если свойство Cancel командной кнопки установлено в "Истина" (.T.), вы можете выбрать командную кнопку нажимая клавишу ESC.

Для получения дополнительной информации о командных кнопках, смотрите Дизайнер форм and Использование элементов управления.

Expand imageПример

Следующий пример демонстрирует, как командные кнопки могут быть добавлены в форму. Свойство Caption используется, чтобы определить текст на командных кнопках и текст указывающий клавишу быстрого доступа каждой кнопки. Свойство Cancel используется, чтобы определить кнопку которая будет выбрана когда вы нажмете ESC.

Метод AddObject используется, чтобы добавить три командные кнопки на форму, позволяя вам изменять направление, в котором элемент управления Line наклоняется или закрывать форму.

  CopyCode imageCopy Code
frmMyForm = CREATEOBJECT('Form')  && Create a Form
frmMyForm.Closable = .F.  && Disable the Control menu box 

frmMyForm.AddObject('shpLine','Line')  && Add a Line control to the form
frmMyForm.AddObject('cmdCmndBtn1','cmdMyCmndBtn1')  && Up Cmnd button
frmMyForm.AddObject('cmdCmndBtn2','cmdMyCmndBtn2')  && Down Cmnd button
frmMyForm.AddObject('cmdCmndBtn3','cmdMyCmndBtn3')  && Quit Cmnd button

frmMyForm.shpLine.Visible = .T.  && Make Line control visible
frmMyForm.shpLine.Top = 20  && Specify Line control row
frmMyForm.shpLine.Left = 125  && Specify Line control column

frmMyForm.cmdCmndBtn1.Visible =.T.  && Up Command button visible
frmMyForm.cmdCmndBtn2.Visible =.T.  && Down" Command button visible
frmMyForm.cmdCmndBtn3.Visible =.T.  && Quit Command button visible

frmMyForm.SHOW  && Display the form
READ EVENTS  && Start event processing

DEFINE CLASS cmdMyCmndBtn1 AS CommandButton  && Create Command button
   Caption = 'Slant \<Up'  && Caption on the Command button
   Left = 50  && Command button column
   Top = 100  && Command button row
   Height = 25  && Command button height
   
   PROCEDURE Click
      ThisForm.shpLine.Visible = .F.  && Hide the Line control
      ThisForm.shpLine.LineSlant ='/'  && Slant up
      ThisForm.shpLine.Visible = .T.  && Show the Line control
ENDDEFINE

DEFINE CLASS cmdMyCmndBtn2 AS CommandButton  && Create Command button
   Caption = 'Slant \<Down'  && Caption on the Command button
   Left = 200  && Command button column
   Top = 100  && Command button row
   Height = 25  && Command button height

   PROCEDURE Click
      ThisForm.shpLine.Visible = .F.  && Hide the Line control
      ThisForm.shpLine.LineSlant ='\'  && Slant down
      ThisForm.shpLine.Visible = .T.  && Show the Line control
ENDDEFINE

DEFINE CLASS cmdMyCmndBtn3 AS CommandButton  && Create Command button
   Caption = '\<Quit'  && Caption on the Command button
   Cancel = .T.  && Default Cancel Command button (Esc)
   Left = 125  && Command button column
   Top = 150  && Command button row
   Height = 25  && Command button height

   PROCEDURE Click
      CLEAR EVENTS  && Stop event processing, close Form
ENDDEFINE

Expand imageСмотрите также