Создает сетку.

Grid

Remarks

Grid - контейнерный объект, который отображает данные в строках и столбцах, и подобен по окну Browse. Grid - также контейнерный объект, который содержит объекты-столбцы. Столбец может содержать объект Header и элементы управления . Поскольку Grid и ее столбцы, заголовки, и элементы управления имеют собственный набор свойств, Вы имеете полный доступ к каждому элементу сетки. Вы можете создать grid, в интерактивном режиме используя Grid Builder.

Для дополнительной информации о создании grid, см. Using Controls.

Example

Следующий пример размещает элемент управление Grid в форму. Таблица "customer" открывается, и ее содержание отображается в grid. Свойство Caption используется для задания отличного от имени поля CUST_ID заголовка столбца - Customer ID. Кнопка помещенная в форму,  закрывает её.

Метод SetAll  используется со свойством DynamicBackColor, чтобы определить цвета фона для записей. Если номер записи нечетный, фон зелёный, иначе белый.

  Copy Code
CLOSE ALL  && Закрывает таблицы и базы данных
OPEN DATABASE (HOME(2) + 'data\testdata')

USE customer IN 0 && Открывает Таблицу "Клиенты"

frmMyForm = CREATEOBJECT('Form') && Создаёт Форму
frmMyForm.Closable = .F. && Отключает закрытие формы крестиком

frmMyForm.AddObject('cmdCommand1','cmdMyCmdBtn') && Добавляет кнопку
frmMyForm.AddObject('grdGrid1','Grid') && Добавляет в форму Grid

frmMyForm.grdGrid1.Left = 25 && Определяет позицию Grid

frmMyForm.grdGrid1.SetAll("DynamicBackColor", ;
"IIF(MOD(RECNO( ), 2)=0, RGB(255,255,255) ;
, RGB(0,255,0))", "Column") && Чередует белые и зеленые записи

frmMyForm.grdGrid1.Visible = .T. && Делает Grid видимым
frmMyForm.cmdCommand1.Visible =.T. && Кнопка "Выход" видима
frmMyForm.grdGrid1.Column1.Header1.Caption = 'ID клиента'

frmMyForm.SHOW && Показывает форму
READ EVENTS && Начинает обработку событий

DEFINE CLASS cmdMyCmdBtn AS CommandButton && Создание кнопки
Caption = '\<Выход' && Заголовок кнопки
Cancel = .T. && Нажатие клавиши Esc приводит к нажатию кнопки
Left = 125 && Горизонтальная позиция кнопки
Top = 210 && Вертикальная позиция кнопки
Height = 25 && Высота кнопки

PROCEDURE Click
CLEAR EVENTS && Прекращается обработка событий, Закрывается форма
CLOSE ALL && Закрывается таблица и база
ENDDEFINE

See Also