Создает заголовок для столбца элемента управления Grid. Столбцы, образующие сетку, имеют заголовки. Объект-заголовок отображает название вверху столбца и может реагировать на события. Для дополнительной информации о создании заголовков в элементе управления Grid смотрите Применение элементов управления.
Замечания
Пример
В следующем примере объект Header со свойством Caption используется для изменения названия первого заголовка в элементе управления Grid.
Элемент управленяи Grid помещается на форму, открывается таблица customer и ее содержимое отображается в сетке. Объект Header и свойство Caption используются для определения другого названия (Customer ID) для первого заголовка в сетке.
Для задания цветов фона записей используется метод SetAll со свойством DynamicBackColor. Если номер отображенной в сетке записи четный, то в качестве значения свойства DynamicBackColor устанавливается белый цвет, в противном случае зеленый. На форму помещается командная кнопка, закрывающая ее.
|
|  Скопировать код |
|---|
CLOSE ALL && Закрываются таблицы и базы данных
OPEN DATABASE (HOME(2) + 'data\testdata')
USE customer IN 0 && Открывается таблица Customer
frmMyForm = CREATEOBJECT('form') && Создается форма
frmMyForm.Closable = .f. && нельзя закрыть объект Form, дважды щелкнув кнопку управляющего меню или выбрав в этом меню команду Close
frmMyForm.AddObject('cmdCommand1','cmdMyCmdBtn') && Помещаем на форму командную кнопку
frmMyForm.AddObject('grdGrid1','Grid') && Помещаем на форму элемент управления Grid
frmMyForm.grdGrid1.Left = 25 && Определяем положение Grid
frmMyForm.grdGrid1.SetAll("DynamicBackColor", ;
"IIF(MOD(RECNO( ), 2)=0, RGB(255,255,255) ;
, RGB(0,255,0))", "Column") && Определяем цвета фона записей в зависимости от четности их номеров - белый и зеленый
frmMyForm.grdGrid1.Visible = .T. && Делаем видимым элемент управления Grid
frmMyForm.cmdCommand1.Visible =.T. && "Quit" Делаем видимой командную кнопку
frmMyForm.grdGrid1.Column1.Header1.Caption = 'Customer ID'
frmMyForm.SHOW && Отображаем форму
READ EVENTS && Начинаем обработку событий
DEFINE CLASS cmdMyCmdBtn AS CommandButton && Создание командной кнопки
Caption = '\<Quit' && Надпись на кнопке
Cancel = .T. && Если пользователь нажмет клавишу ESC, произойдет событие Click для кнопки Cancel.
Left = 125 && Определяем местоположение
Top = 210 && кнопки на форме
Height = 25 && Задаем высоту кнопки
PROCEDURE Click
CLEAR EVENTS && Прекращаем обработку событий, закрываем форму
CLOSE ALL && Закрываются таблицы и базы данных
ENDDEFINE |
Смотрите также
