Определяет, является ли элемент управления CommandButton или OLE Container кнопкой Cancel;это означает, что если пользователь нажмет клавишу ESC, произойдет событие Click для кнопки Cancel. Доступно на этапе разработки и выполнения.

Object.Cancel[ = lExpr]

Expand imageВозвращаемое значение

lExpr

Для свойства Cancel предусмотрены следующие установки:

Усиановка Описание

True (.T.)

CommandButton или OLE Container является кнопкой Cancel.

False (.F.)

(По умолчанию) CommandButton или OLE Container не является кнопкой Cancel.

Expand imageПримечания

Применимо к: CommandButton Control | OLE Container Control

Свойство Cancel применимо к OLE Container только если он содержит елемент управления ActiveX (.ocx) "Acts like a Button".

Expand imageПример

В следующем примере создается командная кнопка и элемент управления OptionGroup, которые помещаются в форму. С помощью свойства Cancel командная кнопка определяется как кнопка Cancel. Если нажать клавишу ESC, произойдет событие Click командной кнопки и процедура события Click выполнит команду CLEAR EVENTS, которая закроет форму и прекратит обработку событий.

Элемент управления OptionGroup содержит три переключателя, и в зависимости от установленного переключателя на экране отображается окружность, эллипс или квадрат. Для создания окружности, эллипса или квадрата используется элемент управления Shape. Событие Click элемента управления OptionGroup, используя структуру DO CASE ... ENDCASE и свойство Value, отображает соответствующую фигуру в результате установки того или иного переключателя.
  CopyCode imageCopy Code
frmMyForm = CREATEOBJECT('Form')  && Create a Form
frmMyForm.Closable = .F.  && Disable the Control menu box 

frmMyForm.AddObject('cmdCommand1','cmdMyCmndBtn')  && Add Command button
frmMyForm.AddObject('opgOptionGroup1','opgMyOptGrp') && Add Option Group
frmMyForm.AddObject('shpCircle1','shpMyCircle')  && Add Circle Shape
frmMyForm.AddObject('shpEllipse1','shpMyEllipse')  && Add Ellipse Shape
frmMyForm.AddObject('shpSquare','shpMySquare')  && Add Box Shape

frmMyForm.cmdCommand1.Visible =.T.  && "Quit" Command button visible

frmMyForm.opgOptionGroup1.Buttons(1).Caption = "\<Circle"
frmMyForm.opgOptionGroup1.Buttons(2).Caption = "\<Ellipse"
frmMyForm.opgOptionGroup1.Buttons(3).Caption = "\<Square"
frmMyForm.opgOptionGroup1.SetAll("Width", 100) && Set Option group width
frmMyForm.opgOptionGroup1.Visible = .T.  && Option Group visible
frmMyForm.opgOptionGroup1.Click  && Show the circle

frmMyForm.SHOW  && Display the form
READ EVENTS  && Start event processing

DEFINE CLASS opgMyOptGrp AS OptionGroup  && Create an Option Group
   ButtonCount = 3  && Three Option buttons
   Top = 10
   Left = 10
   Height = 75
   Width = 100

   PROCEDURE Click 
      ThisForm.shpCircle1.Visible = .F.  && Hide the circle
      ThisForm.shpEllipse1.Visible = .F.  && Hide the ellipse
      ThisForm.shpSquare.Visible = .F.  && Hide the square
      
      DO CASE
         CASE ThisForm.opgOptionGroup1.Value = 1
            ThisForm.shpCircle1.Visible = .T. && Show the circle
         CASE ThisForm.opgOptionGroup1.Value = 2 
            ThisForm.shpEllipse1.Visible = .T.  && Show the ellipse
         CASE ThisForm.opgOptionGroup1.Value = 3 
            ThisForm.shpSquare.Visible = .T.  && Show the square
      ENDCASE
ENDDEFINE

DEFINE CLASS cmdMyCmndBtn AS CommandButton  && Create Command button
   Caption = '\<Quit'  && Caption on the Command button
   Cancel = .T.  && Default Cancel Command button (Esc)
   Left = 125  && Command button column
   Top = 210  && Command button row
   Height = 25  && Command button height

   PROCEDURE Click
      CLEAR EVENTS  && Stop event processing, close Form
ENDDEFINE

DEFINE CLASS shpMyCircle AS SHAPE  && Create a circle
   Top = 10
   Left = 200
   Width = 100
   Height = 100
   Curvature = 99
   BackColor = RGB(255,0,0)  && Red
ENDDEFINE

DEFINE CLASS shpMyEllipse AS SHAPE  && Create an ellipse
   Top = 35
   Left = 200
   Width = 100
   Height = 50
   Curvature = 99
   BackColor = RGB(0,128,0)  && Green
ENDDEFINE

DEFINE CLASS shpMySquare AS SHAPE  && Create a square
   Top = 10
   Left = 200
   Width = 100
   Height = 100
   Curvature = 0
   BackColor = RGB(0,0,255)  && Blue
ENDDEFINE

Expand imageСмотрите также