Присваивает установку некоторого свойства всем элементам управления данного объекта Container или определенному классу таких элементов управления.

Container.SetAll(cProperty, Value [, cClass])

Параметры

cProperty

Задает свойство, которое предстоит установить.
Value

Задает новую установку для свойства. Тип данных Value зависит от устанавливаемого свойства.
cClass

Задает имя класса ( класса, на котором базируется объект, а не базового класса Visual FoxPro для этого объекта).

Замечания

Обращаться : Column | CommandGroup | Container Object | Form | FormSet | Grid | OptionGroup | Page | PageFrame | _SCREEN | ToolBar

Метод SetAll позволяет установить некоторое свойство для всех элементов управления объекта Container или для элементов управления определенного класса. Например, чтобы для всех объектов Column в элементе управления Grid установить в качестве значения свойства BackColor красный цвет, задайте следующее:

  Копировать код
Form1.Grid1.SetAll("BackColor", RGB(255, 0, 0), "Column")

Вы также можете устанавливать свойства для объектов, содержащихся в других объектах контейнера. Чтобы установить зеленый цвет в свойстве ForeColor для объектов Header, содержащихся в каждом из объектов Column элемента управления Grid, выдайте следующую команду:

  Копировать код
Form1.Grid1.SetAll("ForeColor", RGB(0, 255, 0), "Header")

Пример

В следующем примере метод SetAll используется для свойства DynamicBackColor, чтобы задать цвета фона в записях элемента управления Grid. Если запись, отображенная в сетке, имеет четный номер, для ее свойства DynamicBackColor устанавливается белый цвет, в противном случае ѕ зеленый.

Элемент управления Grid помещается в форму, открывается таблица customer и ее содержимое отображается в сетке. Свойство Caption используется для того, чтобы задать другое название заголовка (Customer ID) для поля CUST_ID. В форму включается командная кнопка, закрывающая ее.
  Копировать код
CLOSE ALL  && Close tables and databases
OPEN DATABASE (HOME(2) + 'Data\testdata')

USE customer  IN 0  && Открываем таблицу Customer

frmMyForm = CREATEOBJECT('Form')  && Создаем форму
frmMyForm.Closable = .f.  && Disable the window pop-up menu

frmMyForm.AddObject('cmdCommand1','cmdMyCmdBtn')  && Add Command button
frmMyForm.AddObject('grdGrid1','Grid')  && Add Grid control

frmMyForm.grdGrid1.Left = 25  && Adjust Grid position

frmMyForm.grdGrid1.SetAll("DynamicBackColor", "IIF(MOD(RECNO( ), 2)=0, RGB(255,255,255), RGB(0,255,0))", "Column")  && Alternate white and green records

frmMyForm.grdGrid1.Visible = .T.  && Grid control visible
frmMyForm.cmdCommand1.Visible =.T.  && "Quit" Command button visible
frmMyForm.grdGrid1.Column1.Header1.Caption = 'Customer ID'

frmMyForm.SHOW  && Display the form
READ EVENTS  && Start event processing

DEFINE CLASS cmdMyCmdBtn AS CommandButton  && Create Command button
   Caption = '\<Quit'  && Caption on the Command button
   Cancel = .T.  && Default Cancel Command button (Esc)
   Left = 125  && Command button column
   Top = 210  && Command button row
   Height = 25  && Command button height

   PROCEDURE Click
      CLEAR EVENTS  && Stop event processing, close form
      CLOSE ALL  && Close table and database
ENDDEFINE

Смотреть таже