Добавляет объект в объект контейнерного типа в run time.
|
|---|
Object.AddObject(cName, cClass [, cOLEClass] [, aInit1, aInit2 ...]) |
Параметры
- cName
Указывает имя для ссылки на новый объект.
- cClass
Указывает класс добавляемого объекта.
- cOLEClass
Указывает OLE класс добавляемого объекта.
 Замечание
|
|---|
|
Если вы планируете распространять приложение (run-time)
с введенными компонентами ActiveX Controls, требующими информацию о лицензионных
ключах (например, Microsoft Treeview и Listview), вы не должны использовать метод
AddObject(.....cOLEClass). Вместо этого создайте и сохраните субкласс ваших ActiveX
элементов в файле библиотеки классов VCX. Тогда, в run time, вы можете использовать
методы AddObject или NewObject для добавления этих OleControl классов, содержащих
ваши элементы.
|
- aInit1, aInit2
Указывают параметры, посылаемые событию Init вновь вводимого объекта.
Примечания
Пример
В приведенном ниже примере демонстрируется, как может быть использован метод
AddObject
для добавления управляющих элементов или объектов в форму.
AddObject используется
для добавления управляющего элемента Line control и трех командных кнопок в форму.
Свойство Visible установливается в True (.T.) для элемента
управления Line и командных кнопок. По умолчанию, вводимые
объекты скрыты, когда они добавлены в форму с помощью описываемого метода.
| |  Скопировать код |
|---|
frmMyForm = CREATEOBJECT('Form') && Создается форма
frmMyForm.Closable = .F. && Запрещается блок меню Control формы
frmMyForm.AddObject('shpLine','Line') && В форму добавляется: Line
frmMyForm.AddObject('cmdCmndBtn1','cmdMyCmndBtn1') && Up Cmnd button
frmMyForm.AddObject('cmdCmndBtn2','cmdMyCmndBtn2') && Down Cmnd button
frmMyForm.AddObject('cmdCmndBtn3','cmdMyCmndBtn3') && Quit Cmnd button
frmMyForm.shpLine.Visible = .T. && Делаем Line видимым
frmMyForm.shpLine.Top = 20 && Указываем строку для Line
frmMyForm.shpLine.Left = 125 && Указывает колонку для Line
frmMyForm.cmdCmndBtn1.Visible =.T. && делаем кнопку Up видимой
frmMyForm.cmdCmndBtn2.Visible =.T. && делаем кнопку Down" видимой
frmMyForm.cmdCmndBtn3.Visible =.T. && делаем кнопку Quit видимой
frmMyForm.SHOW && Отображаем форму
READ EVENTS && Начинаем обработке событий
DEFINE CLASS cmdMyCmndBtn1 AS COMMANDBUTTON && Создается командная кнопка
Caption = 'Slant \<Up' && Устанавливается заголовок
Left = 50
Top = 100
Height = 25
PROCEDURE Click
ThisForm.shpLine.Visible = .F. && Скрываем Line
ThisForm.shpLine.LineSlant ='/' && Меняем направление наклона
ThisForm.shpLine.Visible = .T. && Показываем Line
ENDDEFINE
DEFINE CLASS cmdMyCmndBtn2 AS CommandButton
Caption = 'Slant \<Down'
Left = 200
Top = 100
Height = 25
PROCEDURE Click
ThisForm.shpLine.Visible = .F.
ThisForm.shpLine.LineSlant ='\'
ThisForm.shpLine.Visible = .T.
ENDDEFINE
DEFINE CLASS cmdMyCmndBtn3 AS CommandButton && Create Command button
Caption = '\<Quit'
Cancel = .T. && Делает кнопку дефолтной для Cancel (Esc)
Left = 125
Top = 150
Height = 25
PROCEDURE Click
CLEAR EVENTS && Прекращаем обработку событий, закрываем форму
ENDDEFINE |
Смотрите
также
