Определяет - будет ли объект видимым или скрытым. Доступно, как в design, так и в run time.

Object.Visible [= lExpr]

Expand imageВозвращаемое значение

lExpr

Указывает значение, которое определяет будет ли объект видимым или скрытым.

В приведенной ниже таблице приведены возможные значения и их описание для lExpr.

lExpr Описание

True (.T.)

Объект является видимым. (По умолчанию в дизайнере форм)

False (.F.)

Объект скрыт. (По умолчанию в программнои коде)

NoteЗамечание

Даже если объект скрыт, тем не менее у вас есть доступ к нему в прораммном коде.

NoteСовет

Для скрытия объекта при запуске, установите его свойство Visible в False (.F.) во время разработки. Если вы устанавливаете значение свойства Visible в программном коде, вы можете спрятать объект и отобразить его в run time в ответ на конкретное событие.

Expand imageПримечания

Применеятся к: CheckBox | Column | ComboBox | CommandButton | CommandGroup | Container Object | Control Object | EditBox | Form | FormSet | Grid | Image | Label | Line | ListBox | OLE Bound Control | OLE Container Control | OptionButton | OptionGroup | PageFrame | Project Object | _SCREEN | Separator | Shape | Spinner | TextBox | ToolBar

Для объектов Form, когда свойство Visible устанавливается в False (.F.), форма скрыта и бывшие последними из активных наборов форм, формы или прочие объекты становятся активными. Когда Visible устанавливается в True (.T.), форма становится видимой; однако, форма не становится активной. Чтобы сделать форму и видимой и активной в одном шаге, используйте метод Show. Для получения более подробной информации смотрите описание метода Show.

NoteЗамечание

Форма в объекте FormSet не отображается, когда его свойство Visible установлено в значение False (.F.), несмотря на то, что значение свойства Visible формы установлено в True (.T.). Однако, все формы в наборе форм скрыты, если значение свойства Visible набора форм установлено в False (.F.).

Установка свойства Visible формы в True (.T.) не действует на установку свойства Order формы.

Для объектов Separator, значение свойства Visible определяет - появится ли пробел в качестве разделителя, когда его свойство Style установлено в значение 0 (Normal - не отображать линию). Например, когда свойство разделителя Visible установлено в True (.T.), а его свойство Style установлено в значение 0, вместо разделителя появится пробел. Когда свойство Visible разделителя установлено в False (.F.), пробелы не появляются, независимо от установки свойства Style.

В версяих Visual FoxPro  до 5.0, установка свойства Visible для системной переменной _SCREEN не имела никакого эффекта.

Expand imageПример

Приведенный ниже пример отображает форму с управляющим элементом line и тремя командными кнопками, основанными на трех раздельных пльзовательских классах CommandButton. Нажатие на кнопки "Slope Up" или "Slope Down" изменяет наклон линиии нажатие на на кнопку Quit завершает программу. Свойство Visible используется для отображения управляющих элементов в подходящее для этого время.

Приведенные ниже строки кода создают форму и запрещают кнопку Close, так что для выхода из программы должна быть использована кнопка Quit.

  CopyCode imageСкопировать код
frmMyForm = CREATEOBJECT('Form')  
frmMyForm.Closable = .F.

Приведенные ниже строки кода используют метод AddObject для введения управляющего элемента Line и трех командных кнопок в форму.

  CopyCode imageСкопировать код
frmMyForm.AddObject('shpLine','Line')  
frmMyForm.AddObject('cmdCmndBtn1','cmdMyCmndBtn1')  
frmMyForm.AddObject('cmdCmndBtn2','cmdMyCmndBtn2')  
frmMyForm.AddObject('cmdCmndBtn3','cmdMyCmndBtn3')

Свойство Visible устанавливается в значение True (.T.) для управляющих элементов line и командных кнопок для их отображения на форме. Свойства Top и Left определяют расстояние между управляющим элементом line и верхним левым углом формы.

  CopyCode imageСкопировать код
frmMyForm.shpLine.Visible = .T.  
frmMyForm.cmdCmndBtn1.Visible =.T.  
frmMyForm.cmdCmndBtn2.Visible =.T.  
frmMyForm.cmdCmndBtn3.Visible =.T.  
frmMyForm.shpLine.Top = 20  
frmMyForm.shpLine.Left = 125

Метод Show отображает формы и начинает обработку событий с помощью команды READ EVENTS.

  CopyCode imageСкопировать код
frmMyForm.SHOW  
READ EVENTS

Команда DEFINE CLASS определяет три пользовательских класса CommandButton и содержит установки для соответствующих свойств. В событии Click, свойство Visible прячет управляющий элемент line, для того, чтобы можно было изменить направление наклона и отображает его после произведенных изменений. Команда CLEAR EVENTS в событии Click треьуей кнопки останавливает обработку событий и закрывает форму.

  CopyCode imageСкопировать код
DEFINE CLASS cmdMyCmndBtn1 AS COMMANDBUTTON  
   Caption = 'Slope \<Up'  
   Left = 50  
   Top = 100  
   Height = 25  
   PROCEDURE Click
      ThisForm.shpLine.Visible = .F.  
      ThisForm.shpLine.LineSlant ='/'  
      ThisForm.shpLine.Visible = .T.  
ENDDEFINE

DEFINE CLASS cmdMyCmndBtn2 AS CommandButton  
   Caption = 'Slope \<Down'  
   Left = 200  
   Top = 100  
   Height = 25  
   PROCEDURE Click
      ThisForm.shpLine.Visible = .F.  
      ThisForm.shpLine.LineSlant ='\'  
      ThisForm.shpLine.Visible = .T.  
ENDDEFINE

DEFINE CLASS cmdMyCmndBtn3 AS CommandButton  
   Caption = '\<Quit'  
   Cancel = .T.  
   Left = 125  
   Top = 150  
   Height = 25  
   PROCEDURE Click
      CLEAR EVENTS  
ENDDEFINE

Expand imageСмотрите также